import json


Import('env')

mijin_sources = Split("""
    source/mijin/async/coroutine.cpp
    source/mijin/debug/stacktrace.cpp
    source/mijin/debug/symbol_info.cpp
    source/mijin/io/process.cpp
    source/mijin/io/stream.cpp
    source/mijin/net/http.cpp
    source/mijin/net/ip.cpp
    source/mijin/net/socket.cpp
    source/mijin/util/os.cpp
    source/mijin/types/name.cpp
    source/mijin/virtual_filesystem/filesystem.cpp
    source/mijin/virtual_filesystem/stacked.cpp
""")

with open('dependencies.json', 'r') as f:
  dependencies = env.DepsFromJson(json.load(f))

cppdefines = []
if env['BUILD_TYPE'] == 'debug':
    cppdefines += ['MIJIN_DEBUG=1', 'MIJIN_CHECKED_ITERATORS=1']


# SSL libs
if env.get('MIJIN_ENABLE_OPENSSL'):
    cppdefines.append('MIJIN_ENABLE_OPENSSL=1')
    mijin_sources.extend(Split("""
        source/mijin/net/ssl.cpp
    """))

# CURL libs
if env.get('MIJIN_ENABLE_CURL'):
    cppdefines.append('MIJIN_ENABLE_CURL=1')
    mijin_sources.extend(Split("""
        source/mijin/net/request.cpp
    """))

lib_mijin = env.UnityStaticLibrary(
    target = env['LIB_DIR'] + '/mijin',
    source = mijin_sources,
    dependencies = dependencies,
    CPPDEFINES = list(env['CPPDEFINES']) + cppdefines
)

LIB_CONFIG = {
    'CPPPATH': [env.Dir('source')],
    'CPPDEFINES': cppdefines,
    'LIBS': [lib_mijin]
}

Return('LIB_CONFIG')